#######################################################################
# SConscript for gdi winsys

Import('*')

if env['platform'] == 'windows':

    env = env.Clone()

    env.Append(CPPPATH = [
        '#src/gallium/state_trackers/wgl',
        '#src/gallium/winsys/sw',
    ])

    env.Append(LIBS = [
        'gdi32',
        'user32',
        'kernel32',
        'ws2_32',
    ])

    sources = []
    drivers = []

    if True:
        sources = ['gdi_softpipe_winsys.c']
        drivers = [softpipe]

    if env['llvm']:
        sources = ['gdi_llvmpipe_winsys.c']
        drivers = [llvmpipe]

    if env['gcc']:
        sources += ['#src/gallium/state_trackers/wgl/opengl32.mingw.def']
    else:
        sources += ['#src/gallium/state_trackers/wgl/opengl32.def']
        
    drivers += [trace, rbug]

    env['no_import_lib'] = 1

    env.SharedLibrary(
        target ='opengl32',
        source = sources,
        LIBS = wgl + ws_gdi + glapi + mesa + drivers + gallium + glsl + env['LIBS'],
    )
